Inform 7 Home Page / Documentation
§9.13. The past and perfect tenses
The remaining sections of this chapter go into more technical ways to think about the progress of the story through time, and can be skipped at a first reading.
Conditions are clauses which require Inform to make a decision: is such-and-such true, or not true? We have already seen conditions attached to rules using "when":
Instead of waiting when the Sorting Hat is in the Hall: ...
and, as we shall later see, we will often want to write instructions like:
if the Sorting Hat is in the Hall, say "Hermione blinks apprehensively."
The condition is "the Sorting Hat is in the Hall", and during play this will sometimes be true and sometimes false.
A condition in the form "X is Y" is of course written in the present tense, and refers to the current state of affairs. Three other tenses are allowed. First, the present perfect:
if X has been Y ...
is true if it has ever been the case that "X is Y" at the start of any turn (or any action). So, for instance,
if the gate has been open ...
will be valid if and only if the gate has ever been made open by any action (even if it is closed now), or if it started out by being open when play began.
Next is the past tense:
if X was Y ...
holds if and only if "X is Y" was true at the start of the most recent action. This is convenient when trying to describe what has changed in the course of the action, but sometimes also when making the action itself happen. For instance:
if the lantern was switched on, now the lantern is switched off;
if the lantern was switched off, now the lantern is switched on;
Completing the set is the past perfect:
if X had been Y ...
which records whether "X has been Y" was true at the start of the most recent action. All these verbs can of course be negated (though "wasn't" and "hadn't" are disallowed as poor style: we use "was not" and "had not" instead). So for example,
if the player had not been in the Ballroom ...
is true if the player hadn't visited the Ballroom at the start of the most recent action.
Something we must watch out for is that variables might not have the same values in the past that they have now. As a result, writing conditions such as "if the noun has been open" is a bad idea, because in the past "the noun" very likely referred to something different. It is really only safe to talk in the past tense about definite, fixed things: "if the Great Gates of Kiev have been open" would be fine.
|
|
 ExampleTense Boxing
An overview of all the variations of past and present tenses, and how they might be used.
|
|
Here we have a box that prints out its current state and its history each time we open and close it:
"Tense Boxing"
The Temporal Prism is a room. "A room of angled mirrors, in whose surfaces you can see what is now; what just was; what has always been. A final mirror is broken and its frame gapes blackly."
The mysterious box is in the Temporal Prism. It is an openable closed container.
To assess the box:
if the box was not open, say "The box was not open.";
if the box was open, say "The box was open.";
if the box had not been open, say "The box had not been open.";
if the box had been open, say "The box had been open.";
if the box is not open, say "The box is not open.";
if the box is open, say "The box is open.";
if the box has not been open, say "The box has not been open.";
if the box has been open, say "The box has been open."
Before opening the mysterious box:
say "You are about to open the box.";
assess the box.
Before closing the mysterious box:
say "You are about to close the box.";
assess the box.
After opening the mysterious box:
say "You now open the box.";
assess the box.
After closing the mysterious box:
say "You now close the box.";
assess the box.
Note that "was..." and "was not..." and so on may describe conditions more complicated than simple properties: we could equally well ask "if the box has been in the sack", "if the box had been carried by the player", and so on.
The past ("if the box was...") and past perfect ("if the box had been...") are especially useful for cases where we want to report on an action after the state of the item has changed; so, for instance:
After taking the mysterious box:
if the box had not been carried by the player, say "You lift the mysterious box for the first time.";
if the box had been carried by the player, say "You again pick up the mysterious box."
Test me with "open box / close box / open box / take box / drop box / take box".
This is in many respects similar to a rule beginning "After taking the mysterious box for the first time...", but it is superior in most circumstances, for two reasons.
First, it will respond correctly even if the player has somehow carried the box before without taking it explicitly: for instance, if another character gave him the box, if the box were moved into his inventory as a result of another action, or if the player carried the box at the start of play. Inform begins its reckoning of time when the game begins, so if the box is defined as being open at the outset, "if the box has been open" will always be true.
Second, "after taking... for the first time" fires only the first time the player attempts to take something. If the player tried to take the box, failed, and then tried again later, the "for the first time..." rule would not fire; our "if the box has not been carried..." rule would.
|
|
ExampleBruneseau's Journey
A candle which reacts to lighting and blowing actions differently depending on whether it has already been lit once.
|
|
"Sire," said the Minister of the Interior to Napoleon, "yesterday I saw the most intrepid man in your Empire." - "What man is that?" said the Emperor brusquely, "and what has he done?" - "He wants to do something, Sire." - "What is it?" - "To visit the sewers of Paris."
This man existed and his name was Bruneseau.
- Victor Hugo, Les Miserables
Let's say that our intrepid explorer has a candle that can be lit and blown out again, and should accordingly appear unlit, burning, or partly burnt:
"Bruneseau's Journey"
The Sewer Beneath St Denis is a room. "A narrow, stone-lined passageway, with only a little ledge to walk above the level of the refuse that flows down towards the Seine."
The candle is carried by the player. The description of the candle is "A candle, [if the candle has been lit]partially burnt[otherwise]still in pristine condition with untouched wick[end if]."
Instead of examining the lit candle, say "It burns with a pure heart."
The block burning rule is not listed in the check burning rules.
Instead of burning the lit candle:
say "The candle is already lit."
Check burning:
if the noun is not the candle, say "[The noun] cannot profitably be set on fire."
Carry out burning the candle:
now the candle is lit.
Report burning:
if the candle had been lit, say "You relight the candle.";
otherwise say "You light the candle for the first time.".
Understand "blow out [something]" as blowing out. Understand "blow [something] out" as blowing out. Blowing out is an action applying to one thing.
Carry out blowing out the candle:
now the candle is unlit.
Report blowing out:
if the noun is the candle and the candle was lit, say "You blow out [the noun].";
otherwise say "You blow on [the noun], to little effect."
Test me with "x candle / light candle / x candle / blow out candle / x candle".
We must be careful: "if the noun was lit" would throw errors because past-tense rules can only be applied to specific items, not to variables that could be anything.
|
|
ExampleElsie
A door that closes automatically one turn after the player opens it.
|
|
Suppose we want to create an automated door of the sort that closes when it isn't in use. A convenient way is to write a rule that fires "every turn when the sliding door was open". This will be true only if the door was open at the beginning of the turn: if the player just opened it this turn, it stays open, and if it was already closed, it stays closed. Thus:
"Elsie"
The axis-ward is a direction. The opposite of axis-ward is hub-ward. Understand "aw" or "axisward" as axis-ward.
The hub-ward is a direction. The opposite of hub-ward is axis-ward. Understand "hw" or "hubward" as hub-ward.
The Ship's Bridge is a room.
The sliding door is a door. It is axis-ward from Bridge and hub-ward from C Deck. The initial appearance is "There is a door in this wall[if closed] -- or at least, the potential for a door, since currently it is sealed, distinguishable from the rest of the wall only by the warning stripes on its surface[end if]."
Every turn when the sliding door was open:
now the sliding door is closed;
if the player can see the sliding door:
say "The sliding door slips back into place, sealing the wall as though there had never been a breach."
After opening the sliding door:
say "You press the appropriate buttons, and a section of wall slides away."
Test me with "open door / look / enter door / z".
