To implement some of the out of world actions.

• §1. Announce Score Rule
• §2. Switch Score Notification On Rule
• §3. Standard Report Switching Score Notification On Rule
• §4. Switch Score Notification Off Rule
• §5. Standard Report Switching Score Notification Off Rule
• §6. Prefer Sometimes Abbreviated Room Descriptions Rule
• §7. Standard Report Prefer Sometimes Abbreviated Room Descriptions Rule
• §8. Prefer Unabbreviated Room Descriptions Rule
• §9. Standard Report Prefer Unabbreviated Room Descriptions Rule
• §10. Prefer Abbreviated Room Descriptions Rule
• §11. Standard Report Prefer Abbreviated Room Descriptions Rule
• §12. Announce Pronoun Meanings Rule

§1. Announce Score Rule.

[ ANNOUNCE_SCORE_R;
    if (actor ~= player) rfalse;
    if (WorldModelKit`SCORING_CFGV == 0) {
        ANNOUNCE_SCORE_RM('C'); new_line;
    } else {
        ANNOUNCE_SCORE_RM('A'); PrintRank();
    }
];

§2. Switch Score Notification On Rule.

[ SWITCH_SCORE_NOTIFY_ON_R;
    if (actor ~= player) rfalse;
    if (WorldModelKit`SCORING_CFGV == 0) ANNOUNCE_SCORE_R();
    else notify_mode=1;
];

§3. Standard Report Switching Score Notification On Rule.

[ REP_SWITCH_NOTIFY_ON_R;
    if (actor ~= player) rfalse;
    if (WorldModelKit`SCORING_CFGV) {
        REP_SWITCH_NOTIFY_ON_RM('A'); new_line;
    }
];

§4. Switch Score Notification Off Rule.

[ SWITCH_SCORE_NOTIFY_OFF_R;
    if (actor ~= player) rfalse;
    if (WorldModelKit`SCORING_CFGV == 0) ANNOUNCE_SCORE_R();
    else notify_mode=0;
];

§5. Standard Report Switching Score Notification Off Rule.

[ REP_SWITCH_NOTIFY_OFF_R;
    if (actor ~= player) rfalse;
    if (WorldModelKit`SCORING_CFGV) {
        REP_SWITCH_NOTIFY_OFF_RM('A'); new_line;
    }
];

§6. Prefer Sometimes Abbreviated Room Descriptions Rule.

[ PREFER_SOMETIMES_ABBREVIATED_R;
    if (actor ~= player) rfalse;
    lookmode=1;
]; Brief

§7. Standard Report Prefer Sometimes Abbreviated Room Descriptions Rule.

[ REP_PREFER_SOMETIMES_ABBR_R;
    if (actor ~= player) rfalse;
    print (TEXT_TY_Say) Story; REP_PREFER_SOMETIMES_ABBR_RM('A'); new_line;
]; Brief

§8. Prefer Unabbreviated Room Descriptions Rule.

[ PREFER_UNABBREVIATED_R;
    if (actor ~= player) rfalse;
    lookmode=2;
]; Verbose

§9. Standard Report Prefer Unabbreviated Room Descriptions Rule.

[ REP_PREFER_UNABBREVIATED_R;
    if (actor ~= player) rfalse;
    print (TEXT_TY_Say) Story; REP_PREFER_UNABBREVIATED_RM('A'); new_line;
]; Verbose

§10. Prefer Abbreviated Room Descriptions Rule.

[ PREFER_ABBREVIATED_R;
    if (actor ~= player) rfalse;
    lookmode=3;
]; Superbrief

§11. Standard Report Prefer Abbreviated Room Descriptions Rule.

[ REP_PREFER_ABBREVIATED_R;
    if (actor ~= player) rfalse;
    print (TEXT_TY_Say) Story; REP_PREFER_ABBREVIATED_RM('A'); new_line;
]; Superbrief

§12. Announce Pronoun Meanings Rule.

[ ANNOUNCE_PRONOUN_MEANINGS_R x y c d;
    if (actor ~= player) rfalse;
    ANNOUNCE_PRONOUN_MEANINGS_RM('A');

    c = (LanguagePronouns-->0)/3;
    if (player ~= selfobj) c++;

    if (c==0) { ANNOUNCE_PRONOUN_MEANINGS_RM('D'); rtrue; }

    for (x = 1, d = 0 : x <= LanguagePronouns-->0: x = x+3) {
        print "~", (address) LanguagePronouns-->x, "~ ";
        y = LanguagePronouns-->(x+2);
        if (y == NULL) ANNOUNCE_PRONOUN_MEANINGS_RM('C');
        else { ANNOUNCE_PRONOUN_MEANINGS_RM('B'); print (the) y; }
        d++;
        if (d < c-1) print ", ";
        if (d == c-1) {
            if (BasicInformKit`SERIAL_COMMA_CFGF) print ",";
            LW_Response('C');
        }
    }
    if (player ~= selfobj) {
        print "~", (address) ME1__WD, "~ "; ANNOUNCE_PRONOUN_MEANINGS_RM('B');
        c = player; player = selfobj;
        print (the) c; player = c;
    }
    ".";
];