See Position Within Rooms for making the space within a room continuousInform 7 Home Page / Documentation
§3.4. Continuous Spaces and The Outdoors
Suppose we want to blur the boundaries between rooms, in an environment where there are no walls: out of doors, for instance?
The simplest cases involve making something exceptional visible in more than one place. Carnivale features an exceptionally large landmark seen by day; Eddystone an exceptionally bright one by night. Waterworld allows a very distant object (the Sun) to be seen throughout many rooms, but never approached. View of Green Hills gives the player an explicit command for looking through into an adjacent room.
Three systematic examples then present outdoor landscapes with increasing sophistication. Tiny Garden gives the multiple rooms of an extended lawn descriptions which automatically adapt to say which directions lead into further lawn area. Rock Garden provides a relation, "connected with", between rooms, allowing items in one to be seen from the other: an attempt to interact with a visible item in a different area of the garden triggers an implicit going action first. Stately Gardens provides a much larger outdoor area, where larger landmarks are visible from further away, and room descriptions are highly adaptive.
In an outdoor environment, the distinction between a one-move journey and a multiple-move journey is also blurred. Hotel Stechelberg shows a signpost which treats these equally.
See Position Within Rooms for making the space within a room continuous
See Windows for another way to see between locations
See Doors, Staircases, and Bridges for still a third way to be told at least what lies adjacent
See Passers-By, Weather and Astronomical Events for more on describing the sky
|
Start of Chapter 3: Place |
|
Back to §3.3. Position Within Rooms |
|
Onward to §3.5. Doors, Staircases, and Bridges |
|
|
It's tempting to handle the player's inability to interact with something with a simple instead rule:
A view is a kind of backdrop. Instead of doing something other than examining to a view, say "You are too far from [the noun] to do anything but look."
The sun is a view. It is everywhere. The description is "A blazing sun makes you wish you had never been born."
The Sahara is a room. North of the Sahara is More Sahara. North of More Sahara is Yet Further Sahara.
Unfortunately, the rule does not address the case where the object in question is the second noun; so for instance the following example reveals the difficulty:
A view is a kind of backdrop. Instead of doing something other than examining to a view, say "You are too far from [the noun] to do anything but look."
The sun is a view. It is everywhere. The description is "A blazing sun makes you wish you had never been born."
The Sahara is a room. North of the Sahara is More Sahara. North of More Sahara is Yet Further Sahara.
Test me with "x sun / get sun / n / x sun / n / x sun / tie rope to the sun".
...where the response here behaves as though the sun is in reach. If we had a fully implemented tying action, the player would (even more disastrously) be allowed to lasso celestial objects.
We could add a second instead rule as well:
Instead of doing something other than examining when the noun is a view:
say "You are too far from [the noun] to do anything but look."
Instead of doing something other than examining when the second noun is a view:
say "You are too far from [the second noun] to do anything but look."
The sun is a view. It is everywhere. The description is "A blazing sun makes you wish you had never been born."
The Sahara is a room. North of the Sahara is More Sahara. North of More Sahara is Yet Further Sahara.
Test me with "x sun / get sun / n / x sun / n / x sun / tie rope to sun".
|
|
Sometimes we want to make a list of something too complicated to express in a say list... phrase. When this happens, we can instead mark all the items we want to mention as "marked for listing".
In this case, we have a lawn area made up of four rooms. We want each room to automatically describe the directions leading to the other parts of the lawn. To do this, we will first determine which directions are relevant and mark those for listing, then list them.
The Herb Garden is a room. "Along this side of the house run your great-aunt's herb beds."
A Grassy Room is a kind of room. The printed name of a Grassy Room is usually "Lawn". The description of a Grassy Room is "The grass underfoot is thick and green. The lawn extends to [grassy directions] from here."
The following phrase goes through all the directions in the compass and marks the ones that are interesting to us at the moment.
To say grassy directions:
repeat with that way running through directions:
if the room that way from the location is a grassy room,
now that way is marked for listing;
say "[a list of directions which are marked for listing]";
now every direction is not marked for listing.
Lawn1 is west of the Herb Garden. It contains a picnic table and a wicker basket. Lawn2 is south of Lawn1 and southeast of Lawn4. Lawn3 is southwest of Lawn1, west of Lawn2, and south of Lawn4. Lawn4 is west of Lawn1. Lawn4 contains a birdbath. The birdbath is fixed in place.
|
|
The following rule appends a paragraph to every room description. We need not worry about doors (despite the pass in the Bernese Oberland known figuratively as the "Little Door").
After looking:
say "Yellow arms on the signpost point:-[line break]";
repeat with destination running through interesting rooms:
let the way be the best route from the location to the destination;
if the way is a direction, say " [way] for [the destination]: [number of moves from the location to the destination] Std."
Hotel Stechelberg is a room. "The wooden hiking inn at the end of the road, with flowerboxes, canton flags, outdoor tables and a triangular paddock for the cows contesting the annual Miss Stechelberg competition. Otto and Marianne do cheerful innkeeper things, while the sun blazes from a gentian-blue sky."
North of Hotel Stechelberg is Trummelbachfalle. North of Trummelbachfalle is Lauterbrunnen. Lauterbrunnen is interesting.
Southeast of Hotel Stechelberg is Trachsellauenen. Trachsellauenen is interesting.
With a bit more work, the result might be:
Hotel Stechelberg
The wooden hiking inn at the end of the road, with flowerboxes, canton flags, outdoor tables and a triangular paddock for the cows contesting the annual Miss Stechelberg competition. Otto and Marianne do cheerful innkeeper things, while the sun blazes from a gentian-blue sky.
Yellow arms on the signpost point:-
north for Lauterbrunnen: 2 Std.
west for Sefinental: 2 Std.
west for Schilthorn: 6 Std.
southeast for Trachsellauenen: 1 Std.
southeast for Oberhornsee: 3 Std.
|
|
Suppose we want to make an object that (unlike a backdrop) is definitely located in one room, but can be seen from far off. We want to allow the player to interact with it from a distance, but only using those actions that require visibility. Other actions should be denied:
The Fairground is a region. Park Entrance, By the Wheel, and Candy Stand are in Fairground. Candy Stand is north of By the Wheel. Park Entrance is west of Candy Stand and northwest of By the Wheel.
The ferris wheel is scenery in By the Wheel. "It is extravagantly tall and carries several dozen glass gondolas for riders."
The description of By the Wheel is "You stand at the foot of an enormous ferris wheel, which turns far too quickly and never seems to stop for new riders."
The description of Park Entrance is "You are now just inside the gates. Behind you snakes a triple line of fairgoers all the way down the length of the valley to the railway station. Roughly southeast of here is the ferris wheel, towering over the other attractions."
The description of Candy Stand is "A hut in pale pink and baby blue dispenses marshmallow death's-heads, sugar-beetles, and other such treats. The giant ferris wheel is just off to the south from here."
As the descriptions make clear, the ferris wheel should be visible from everywhere in the fair, so we'll borrow a line from the Activities chapter to make that happen:
After deciding the scope of the player:
if the location is in Fairground, place the ferris wheel in scope.
"Scope" determines what the player can interact with; by writing this rule, we make Inform understand all commands that refer to the ferris wheel when the player is anywhere in the fairground, instead of responding with
as it normally would.
Now, by default, if the player were to type TOUCH FERRIS WHEEL while in another room, he would get the response
This may not be quite what we want, but we can replace this text with our own reaching inside rule:
Rule for reaching inside a room:
say "You can only look from this distance.";
deny access.
And because our accessibility rules are considered before the "Instead" phase, we can write the following rule confident that it will apply only when the player is in fact in range to touch the ferris wheel:
Instead of touching the ferris wheel:
say "You don't dare: it's spinning too fast."
Test me with "x ferris wheel / touch ferris wheel / se / x ferris wheel / touch ferris wheel".
|
|
Using the compass directions in commands is a little bit finicky because directions are forbidden to figure in any interactions involving touch. (Really, directions are more a concept than an object; this is a compromise situation.) In any case, if we want to write a new command involving these, we need to be sure to specify that the direction is a visible thing. For instance:
The Lighthouse is a room. "A lonely place, but in these tense times, no one but the lighthouse keeper and a few trusted agents are allowed on the grounds at all, for fear of sabotage."
The light is a fixed in place thing in the Lighthouse. "At the center of the room is the light itself, a 1000-Watt tungsten halogen light powered by diesel generator, and having a visible range of twenty-six nautical miles." Understand "lamp" as the light. It is lit. The light has a a direction called heading. The heading of the light is north.
Understand "turn [something] [a direction]" as reorienting it to. Reorienting it to is an action applying to two things.
will give us
>turn light northeast
You must name something more substantial.
To avoid this mystifying result:
The Lighthouse is a room. "A lonely place, but in these tense times, no one but the lighthouse keeper and a few trusted agents are allowed on the grounds at all, for fear of sabotage."
The light is a fixed in place thing in the Lighthouse. "At the center of the room is the light itself, a 1000-Watt tungsten halogen light powered by diesel generator, and having a visible range of twenty-six nautical miles." Understand "lamp" as the light. It is lit. The light has a direction called heading. The heading of the light is north.
Understand "turn [something] [a direction]" as reorienting it to. Reorienting it to is an action applying to one thing and one visible thing.
Instead of turning the light, say "Try turning the light to the direction of your choice."
Check reorienting it to: if the noun is not the light, say "You couldn't do so meaningfully." instead; if the second noun is up or the second noun is down, say "The light only points in compass directions." instead.
And now that's done, we have a little fun calculating where the beam hits:
Carry out reorienting it to:
now the heading of the light is the second noun;
let way be the heading of the light;
let place be the room way from the Lighthouse;
while place is a room and place is lower than Lighthouse:
let place be the room way from the place;
if place is not a room, now the beam is nowhere;
otherwise move beam to the place.
Report reorienting it to: say "The light now points [heading of the light][if the beam is in a room], spotlighting [the holder of the beam][otherwise], into empty space[end if]."
The beam is a lit thing. Understand "light" or "brilliant" as the beam. "Brilliant light from the lighthouse floods the whole area." It is fixed in place. Instead of doing something other than examining to the beam: say "The light is, of course, intangible." The description is "The light is coming from the lighthouse, since the lamp is apparently pointed this way."
Altitude is a kind of value. 200 ft specifies an altitude. A room has an altitude. The altitude of a room is usually 50 ft. The altitude of the Lighthouse is 100 ft.
The Jetty is south of the Lighthouse. "During daylight hours, a fine place to catch almost unlimited supplies of crayfish. Less entertaining by night."
North of the Lighthouse is the Uphill Road. The altitude of Uphill Road is 75 ft. North of Uphill Road is Hilltop. The altitude of Hilltop is 110 ft. The description of Hilltop is "The highest natural point around for miles; sometimes you will sit up here and watch for the lighthouse supply ship, the Lady Loch."
Northeast of the Lighthouse is Open Field. East of the Lighthouse is Stanley Creek Valley. The description of Stanley Creek is "This place used to have some other name meaning Ghost Valley in the aboriginal language, but it was piously renamed by missionaries." Train Trestle is east of the Stanley Creek Valley. "The now-abandoned track of the Bush Pacific Railway runs here, above Stanley Creek." The altitude of Train Trestle is 100 ft.
Before going from a room (called source) to a room (called destination):
if source is lower than destination:
say "It's an uphill climb...";
otherwise:
if destination is lower than source, say "You're heading downhill now...";
otherwise say "It's a straight shot."
Test me with "turn lamp / turn lamp down / turn lamp east / e / e".
All very loosely based on the Eddystone Point lighthouse of Tasmania, built in 1889, and forbiddingly remote even today. George Isaacs, a child growing up in the lighthouse, remembers the plentiful crayfish.
|
|
A map of linked rooms works well for modeling enclosed or indoor space, and somewhat less well for modeling large open spaces, where a person should reasonably be able to see things which are much too far away to touch. With some modifications to scoping, though, we can create an environment where objects in nearby rooms are described and viewable, and where the player will automatically move towards distant items before interacting with them physically.
Intervisibility relates rooms to each other in groups. The verb to be connected with means the intervisibility relation.
Definition: a room is inter-visible if it is connected with more than one room.
After deciding the scope of the player when the location is an inter-visible room:
repeat with other place running through rooms which are connected with the location:
unless the other place is the location, place the other place in scope.
Rule for reaching inside a room (called target) which is connected with the location:
let way be the best route from the location to the target;
if the way is not a direction:
say "You can't get over to [the target] from here.";
deny access;
say "(first heading [way])[command clarification break]";
try going way;
if the player is in the target, allow access;
otherwise deny access.
After looking when the location is an inter-visible room:
repeat with other place running through rooms which are connected with the location:
if the other place is not the location, describe locale for other place.
Rock Garden West is west of Rock Garden East. Rock Garden East contains a rake. Rock Garden West contains a bench and a maple leaf. The bench is an enterable supporter.
Test me with "get rake / drop rake / sit on bench / get rake".
|
|
Suppose a game in which the player is wandering an open landscape with long vistas, allowing him to LOOK in some direction, or even look at an adjacent location.
Corinth is a room. Athens is east of Corinth. Epidaurus is southeast of Corinth and east of Mycenae. Mycenae is south of Corinth. Olympia is west of Mycenae. Argos is south of Mycenae. Thebes is northwest of Athens. Pylos is south of Olympia. Sparta is east of Pylos and south of Argos. Delphi is northwest of Thebes.
Carry out facing:
let the viewed item be the room noun from the location;
if the viewed item is not a room, say "You can't see anything promising that way." instead;
try looking toward the viewed item.
In rules about action handling, "noun" refers to the first object that the player has mentioned in his command, so if the player typed >LOOK WEST, "let the viewed item be the room noun from the location" would be processed as "let the viewed item be the room west from the location", and so on.
We can at need override the default behavior, if it is not going to be appropriate for the player to see the next room over. There is only sky above at any time, so...
Understand "look toward [any adjacent room]" as looking toward. Understand "examine [any adjacent room]" as looking toward.
Carry out looking toward:
say "You make out [the noun] that way."
This design allows us to create descriptions for rooms (as seen from the outside) which will work regardless of where we're looking from. For instance:
Instead of looking toward Athens:
say "Even from here you can make out the silhouette of the Acropolis."
Test me with "look north / look south / look up / look east / east / look west".
|
|
This time we're going to assume that the player can see into any room that is on a line of sight within one or two steps of travel.
After deciding the scope of the player:
repeat with the way running through directions:
let first step be the room the way from the location;
if the first step is a room:
place the first step in scope;
let second step be the room the way from the first step;
if the second step is a room, place the second step in scope;
place the obelisk in scope.
The obelisk is so large that it can be seen from every room. If we had a number of such large monuments we might want to write a systematic routine to handle them, but this will do for now.
The room description heading rule is not listed in the carry out looking rules.
Now, we set things up so that the surrounding areas are described automatically as part of the room description:
Building description is a truth state that varies. Building description is false.
After looking when the location is an outdoors room:
now count of sentences is 0;
now building description is true;
repeat with way running through directions:
let space be the room way from the location;
if space is an outdoors room, silently try looking toward space;
if the obelisk is not in the location and the obelisk is unmentioned:
let the way be the best route from location to the Upper Terrace;
if the way is a direction, say "[The obelisk] is proudly visible on [the way] horizon. [run paragraph on]";
increment the count of sentences;
now building description is false;
unless the count of sentences is 0:
say paragraph break.
But perhaps there are a few rooms where we do not wish that to happen, so we'll build in exceptions for those.
After looking in the rose garden:
say "Otherwise, you are quite cut off.".
And suppose we want to allow the player to look in any direction:
Understand "look [direction]" or "look to/toward [direction]" as facing.
Carry out facing:
let the viewed item be the room noun from the location;
if the viewed item is not a room:
if the location is indoors, say "Your view is restricted by the lack of doors or windows in that direction." instead;
otherwise say "You can't see anything promising that way." instead;
try looking toward the viewed item.
We also need to tell distant rooms how to describe themselves.
Understand "look toward [any adjacent room]" as looking toward.
Check looking toward a room which does not contain something mentionable:
if building description is false:
say "You can't make out anything of interest that way." instead.
Carry out looking toward:
now every thing is unmentioned;
now the chosen direction is the best route from the location to the noun;
now the second noun is the room the chosen direction from the noun;
if the noun contains something mentionable:
repeat with item running through mentionable things in the noun:
carry out the writing a distant paragraph about activity with the item;
if the noun contains something mentionable:
increment the count of sentences;
choose row count of sentences in the Table of Distance Sentences;
if the second noun is an outdoors room and the second noun contains something mentionable, say "[both entry] [run paragraph on]";
otherwise say "[here entry] [run paragraph on]";
otherwise:
if the second noun is an outdoors room and the second noun contains something mentionable:
increment the count of sentences;
choose row count of sentences in the Table of Distance Sentences;
say "[there entry] [run paragraph on]";
if building description is false:
say paragraph break.
And again, some exception needs to be made for seeing what's in the dip in the ground:
Instead of looking toward the Ha-ha:
now the chosen direction is the best route from the location to the noun;
now the second noun is the room the chosen direction from the noun;
if the second noun is an outdoors room and the second noun contains something mentionable:
increment the count of sentences;
choose row count of sentences in the Table of Distance Sentences;
say "[there entry] [run paragraph on]".
The following is to account for cases where the player types "look toward obelisk" or similar, rather than looking toward a room:
The following is arguably an unnecessary refinement, but the listing of items in the distance gets a bit repetitive unless we vary the sentence structure.
|
both |
here |
there |
|
"From here, you make out [a list of mentionable things in the noun] a little way [chosen direction], and, further on, [a list of mentionable things in the second noun]." |
"From here, you make out [a list of mentionable things in the noun] [if the noun is not adjacent to the location]some distance [end if]to [the chosen direction]." |
"From here, you make out [a list of mentionable things in the second noun] some distance [chosen direction]." |
|
"To [the chosen direction] there [is-are a list of mentionable things in the noun], partly obscuring your further view of [a list of mentionable things in the second noun]." |
"To [the chosen direction] there [is-are a list of mentionable things in the noun]." |
"Quite a way [chosen direction] [is-are a list of mentionable things in the second noun]." |
|
"Then [chosen direction] [is-are a list of mentionable things in the noun], and beyond [a list of mentionable things in the second noun]." |
"Meanwhile, to [the chosen direction] [is-are a list of mentionable things in the noun]." |
"Meanwhile, [chosen direction] in the middle distance [is-are a list of mentionable things in the second noun]." |
|
"When you turn [chosen direction], you see [a list of mentionable things in the noun], and somewhat further on [a list of mentionable things in the second noun]." |
"When you turn [chosen direction], you see [a list of mentionable things in the noun]." |
"If you turn [chosen direction], you see [a list of mentionable things in the second noun] some way off." |
|
"Somewhere generally [chosen direction] [is-are a list of mentionable things in the noun], beyond which, [a list of mentionable things in the second noun]." |
"Roughly [chosen direction] [is-are a list of mentionable things in the noun]." |
"Moreover, in the [chosen direction] distance [is-are a list of mentionable things in the second noun]." |
|
"[The chosen direction] shows [a list of mentionable things in the noun] and then [a list of mentionable things in the second noun]." |
"And to [the chosen direction] [a list of mentionable things in the noun]." |
"Meanwhile, [chosen direction] in the middle distance [is-are a list of mentionable things in the second noun]." |
|
"Then, [chosen direction], [is-are a list of mentionable things in the noun], and beyond [a list of mentionable things in the second noun]." |
"Meanwhile, to [the chosen direction] [is-are a list of mentionable things in the noun]." |
"Meanwhile, [chosen direction] in the middle distance [is-are a list of mentionable things in the second noun]." |
|
"Finally, [chosen direction], [is-are a list of mentionable things in the noun], somewhat nearer than [a list of mentionable things in the second noun]." |
"Finally, to [the chosen direction] [is-are a list of mentionable things in the noun]." |
"Finally, [chosen direction] in the middle distance [is-are a list of mentionable things in the second noun]." |
Now, our ability to view things at a distance should be determined by the size of the things we're trying to see:
A height is a kind of value. 10 feet 11 inches specifies a height. 10 feet 11 specifies a height. The verb to stand means the height property. The verb to measure means the height property. A thing has a height. The height of a thing is usually 3 feet 0.
Definition: a thing is tiny if its height is 0 feet 6 inches or less.
Definition: a thing is short if its height is 3 feet 0 or less.
Definition: a thing is tall if its height is 6 feet 0 or more.
The height of a man is usually 5 feet 10 inches. The height of a woman is usually 5 feet 6 inches.
Definition: a thing is monumental if it is taller than 25 feet 0 inches.
Definition: a thing is mentionable if it stands tall enough to see.
To decide whether (item - a thing) stands tall enough to see:
if the item is in the Rose Garden and the item is shorter than the roses, no;
if the item is mentioned, no;
if the item is in an adjacent room and item is taller than 2 feet 0, yes;
if the item is taller than 4 feet 0, yes;
no.
Instead of examining something which is within a room (called the space) which is not the location:
if the location is adjacent to the space:
if the noun is tiny, say "It is too far from here for you to make out much detail about [the noun]." instead;
let way be the best route from the location to the space;
if the way is a direction, say "You gaze off [way] at [the noun]...";
continue the action;
otherwise:
if the noun is short, say "It is too far from here for you to make out much detail about [the noun]." instead;
let way be the best route from the location to the space;
if the way is a direction, say "You gaze off [way] into the distance at [the noun]...";
continue the action.
We might also want to be able to override, manually, the way distant things are described.
Rule for writing a distant paragraph about the lily pond:
if the second noun is a room and something mentionable is in the second noun, say "A [lily pond], [chosen direction], patchily reflects [a list of mentionable things in the second noun] on the far side. [run paragraph on]";
otherwise say "To [the chosen direction], [a lily pond] shimmers in the sunlight. [run paragraph on]"
Rule for writing a distant paragraph about the roses:
if something in the Rose Garden is taller than the roses,
say "Over the tops of [the roses], [chosen direction], you see [a list of mentionable things in the rose garden]. [run paragraph on]";
otherwise say "Immediately [chosen direction] is [the roses]. [run paragraph on]"
Rule for writing a distant paragraph about the obelisk:
if a mentionable thing in the Upper Terrace is shorter than the obelisk,
say "A stupidly grand [obelisk], [chosen direction], towers over [a list of mentionable things in the Upper Terrace]. [run paragraph on]";
otherwise say "To [the chosen direction], you can't help noticing [the obelisk], which is much larger than any object really needs to be. [run paragraph on]".
After writing a distant paragraph about something:
increment the count of sentences.
Moreover, proximate things might have special descriptions too.
Rule for writing a paragraph about something tiny when the location is outdoors:
if the location is the Gravel Circle,
say "Abandoned in the gravel [is-are a list of unmentioned tiny things in the location]. [run paragraph on]";
otherwise say "Half trampled into the grass, and easy to miss, [is-are a list of unmentioned tiny things in the location]. [run paragraph on]"
Before doing something other than examining or approaching to something which is not within the location:
if the player has the noun, continue the action;
say "(first going over to [the noun])[line break]";
try approaching the noun;
if the noun is not within the location, stop the action.
Understand "go toward/to/towards/near [something]" or "approach [something]" as approaching.
Check approaching:
if the player is in something, say "You'll have to get up." instead;
if the noun is within the location, say "You're as close to [the noun] as you can get." instead;
let space be the location of the noun;
if the space is not a room, say "You don't quite see how to get there." instead;
let way be the best route from the location to the space;
unless way is a direction,
say "You can't see how to get over there from here." instead.
To head to (space - a room):
let the way be the best route from the location to the space;
if the space is adjacent to the location,
try going way;
otherwise silently try going way.
Carry out approaching:
let space be the location of the noun;
while the space is not the location:
head to space.
This is a bit primitive, since if we had an occasion where going was blocked, we could get stuck in a loop. So we would need to be careful, but for this example it won't arise.
Going state is a truth state that varies. Going state is false.
The description of a room is usually "[if going state is true]You drift [noun] across the open lawn[direction relative to obelisk]. [end if]An absolutely phenomenal quantity of manicured turf stretches from where you stand in almost every direction."
To say direction relative to obelisk:
if obelisk is in the location:
say ", as though drawn magnetically to the foot of the monument";
otherwise:
let way be the best route from the location to the Upper Terrace;
if way is the noun, say ", drawn towards [the obelisk]";
if the way is the opposite of the noun, say ", keeping [the obelisk] more or less at your back".
When play begins:
now the left hand status line is "Idyllic";
now the right hand status line is " ".
The Gravel Circle, the Ha-ha, the Sheep Field, the Open Lawn, the Croquet Ground, the Rose Garden, the Upper Terrace, the Middle Terrace, and the Lower Terrace are outdoors.
The Middle Terrace is north of the Lower Terrace and south of the Upper Terrace. The lily pond is fixed in place in the Middle Terrace."You [if going state is true]come to[otherwise]are at[end if] the north edge of a perfectly round lily pond, bordered with stones. Its surface patchily reflects [the marble anteater] on the south bank." A tent peg and a wilted orchid are in the Middle Terrace. The tent peg measures 0 feet 6. The orchid measures 0 feet 4.
The description of the Lower Terrace is "[if going state is true]You climb [noun] up a small hillock[direction relative to obelisk][otherwise]You stand on a short, round, entirely artificial hillock[end if]."
The marble anteater is a fixed in place thing in the Lower Terrace. The height of marble anteater is 6 feet 2 inches."A marble anteater stands on a pedestal at the top of the hill. In the bright sunlight the white marble makes a striking contrast with [the obelisk] in the distance." The description is "The anteater is very much more than life-size."
The obelisk of black granite is a fixed in place thing in the Upper Terrace."Now that you are at the foot of it, you can properly appreciate the stupid immensity of the obelisk, pointing stonily at heaven." The height of the obelisk is 50 feet 0 inches. The description of the obelisk is "It stands ridiculously tall, and has an inscription on the face."
The inscription is part of the obelisk. The height of the inscription is 0 feet 3 inches. The description of the inscription is "You can't read the squirming, pointed letters, but they make you uneasy.".
The Gravel Circle is west of the Upper Terrace, northwest of the Middle Terrace, and north of the Croquet Ground. The description of the Gravel Circle is "[if going state is true]You head [noun] until the lawn thins and[otherwise]Here the lawn[end if] gives way to a circle of raked gravel, which crunches pleasingly beneath you."
Instead of going northwest in the Upper Terrace, try going north.
The Ha-ha is north of the Gravel Circle and northwest of the Upper Terrace. The description of the Ha-ha is "[if going state is true]The land dips here so suddenly that you do not know the dip is there until you're in it; but it prevents livestock from crossing barriers, and that is the important thing[otherwise]You are at the base of a steep-sided depression, so the lawn continues north and south more or less at the level of your head[end if].
The tip of [the obelisk] is the only thing you can make out from this depression, off to the southeast.". North of the Ha-ha is the Sheep Field. In the Sheep Field is an animal called a black sheep. The black sheep stands 4 feet 3 inches."A black sheep grazes placidly nearby." The description of the black sheep is "It reminds you of your Uncle Tim."
Before going from the Ha-ha:
say "It's a bit of a scramble to get back up the side of the depression, and you keep slipping in the damp grass. But you manage at last."
The Rose Garden is southwest of the Lower Terrace. The thicket of red roses is a fixed in place thing in the Rose Garden. The thicket stands 4 feet 2 inches."Heavy red roses grow over a roughly horseshoe-shaped wall around you. Over this barrier, the head of [the marble anteater] is visible to the northwest, and the tip of [the obelisk] in the distance."
The description of the Rose Garden is "[if going state is true]You slip [noun] into the enclosure of the rose garden. [end if]The rest of the park, and the world, seems muted and quiet."
Instead of smelling the rose garden: try smelling the roses. Instead of smelling the roses, say "The smell tickles the back of your throat and makes you want to cough."
Instead of listening to the rose garden:
say "You can't hear anything at all."
The Open Lawn is north of the Rose Garden, west of the Lower Terrace, and southwest of the Middle Terrace. The Croquet Ground is north of the Open Lawn, west of the Middle Terrace, southwest of the Upper Terrace, and northwest of the Lower Terrace.
A discarded champagne cork is in the Open Lawn. It stands 0 feet 2 inches.
A stone bench is an enterable supporter in the Croquet Ground. It stands 3 feet 8 inches."There is a stone bench here -- a sort of stone sofa, really, with nymphs disporting themselves on the arms and back." The description of the bench is "It used to be a Roman sarcophagus -- hence the nymphs -- but someone has thoughtfully recarved it as lawn furniture."
The half-size Bentley is a vehicle in the Gravel Circle."A sort of child's-toy version of a Bentley is parked [if something parkable is in the location]beside [the tallest parkable thing in the location][otherwise]close at hand[end if]." The description of the half-size Bentley is "Of beautiful and unambiguously luxurious lines, but sized down to hold only one or (at a stretch) two people, and powered by electricity." The half-size Bentley stands 3 feet 6 inches.
Definition: a thing is parkable if it is not a person and it is not the Bentley.
Instead of touching the obelisk, say "Though it is black stone in sunlight, the obelisk is very cold to the touch."
Test me with "look east / look toward obelisk / s / s / e / sw / ne / n / n / w / n / n / examine obelisk / touch obelisk / read inscription".
